Contract Name:
PWNSimpleLoan
Contract Source Code:
<i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import "@openzeppelin/interfaces/IERC20.sol";
import "@openzeppelin/interfaces/IERC721.sol";
import "@openzeppelin/interfaces/IERC1155.sol";
import "@openzeppelin/token/ERC20/extensions/draft-IERC20Permit.sol";
import "@openzeppelin/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/utils/introspection/ERC165Checker.sol";
import "@MT/interfaces/ICryptoKitties.sol";
library MultiToken {
using ERC165Checker for address;
using SafeERC20 for IERC20;
bytes4 public constant ERC20_INTERFACE_ID = 0x36372b07;
bytes4 public constant ERC721_INTERFACE_ID = 0x80ac58cd;
bytes4 public constant ERC1155_INTERFACE_ID = 0xd9b67a26;
bytes4 public constant CRYPTO_KITTIES_INTERFACE_ID = 0x9a20483d;
/**
* @title Category
* @dev Enum representation Asset category.
*/
enum Category {
ERC20,
ERC721,
ERC1155,
CryptoKitties
}
/**
* @title Asset
* @param category Corresponding asset category.
* @param assetAddress Address of the token contract defining the asset.
* @param id TokenID of an NFT or 0.
* @param amount Amount of fungible tokens or 0 -> 1.
*/
struct Asset {
Category category;
address assetAddress;
uint256 id;
uint256 amount;
}
/*----------------------------------------------------------*|
|* # TRANSFER ASSET *|
|*----------------------------------------------------------*/
/**
* transferAssetFrom
* @dev Wrapping function for `transferFrom` calls on various token interfaces.
* If `source` is `address(this)`, function `transfer` is called instead of `transferFrom` for ERC20 category.
* @param asset Struct defining all necessary context of a token.
* @param source Account/address that provided the allowance.
* @param dest Destination address.
*/
function transferAssetFrom(Asset memory asset, address source, address dest) internal {
_transferAssetFrom(asset, source, dest, false);
}
/**
* safeTransferAssetFrom
* @dev Wrapping function for `safeTransferFrom` calls on various token interfaces.
* If `source` is `address(this)`, function `transfer` is called instead of `transferFrom` for ERC20 category.
* @param asset Struct defining all necessary context of a token.
* @param source Account/address that provided the allowance.
* @param dest Destination address.
*/
function safeTransferAssetFrom(Asset memory asset, address source, address dest) internal {
_transferAssetFrom(asset, source, dest, true);
}
function _transferAssetFrom(Asset memory asset, address source, address dest, bool isSafe) private {
if (asset.category == Category.ERC20) {
if (source == address(this))
IERC20(asset.assetAddress).safeTransfer(dest, asset.amount);
else
IERC20(asset.assetAddress).safeTransferFrom(source, dest, asset.amount);
} else if (asset.category == Category.ERC721) {
if (!isSafe)
IERC721(asset.assetAddress).transferFrom(source, dest, asset.id);
else
IERC721(asset.assetAddress).safeTransferFrom(source, dest, asset.id, "");
} else if (asset.category == Category.ERC1155) {
IERC1155(asset.assetAddress).safeTransferFrom(source, dest, asset.id, asset.amount == 0 ? 1 : asset.amount, "");
} else if (asset.category == Category.CryptoKitties) {
if (source == address(this))
ICryptoKitties(asset.assetAddress).transfer(dest, asset.id);
else
ICryptoKitties(asset.assetAddress).transferFrom(source, dest, asset.id);
} else {
revert("MultiToken: Unsupported category");
}
}
/**
* getTransferAmount
* @dev Get amount of asset that would be transferred.
* NFTs (ERC721, CryptoKitties & ERC1155 with amount 0) with return 1.
* Fungible tokens will return its amount (ERC20 with 0 amount is valid state).
* In combination with `MultiToken.balanceOf`, `getTransferAmount` can be used to check successful asset transfer.
* @param asset Struct defining all necessary context of a token.
* @return Number of tokens that would be transferred of the asset.
*/
function getTransferAmount(Asset memory asset) internal pure returns (uint256) {
if (asset.category == Category.ERC20)
return asset.amount;
else if (asset.category == Category.ERC1155 && asset.amount > 0)
return asset.amount;
else // Return 1 for ERC721, CryptoKitties and ERC1155 used as NFTs (amount = 0)
return 1;
}
/*----------------------------------------------------------*|
|* # TRANSFER ASSET CALLDATA *|
|*----------------------------------------------------------*/
/**
* transferAssetFromCalldata
* @dev Wrapping function for `transferFrom` calladata on various token interfaces.
* If `fromSender` is true, function `transfer` is returned instead of `transferFrom` for ERC20 category.
* @param asset Struct defining all necessary context of a token.
* @param source Account/address that provided the allowance.
* @param dest Destination address.
*/
function transferAssetFromCalldata(Asset memory asset, address source, address dest, bool fromSender) pure internal returns (bytes memory) {
return _transferAssetFromCalldata(asset, source, dest, fromSender, false);
}
/**
* safeTransferAssetFromCalldata
* @dev Wrapping function for `safeTransferFrom` calladata on various token interfaces.
* If `fromSender` is true, function `transfer` is returned instead of `transferFrom` for ERC20 category.
* @param asset Struct defining all necessary context of a token.
* @param source Account/address that provided the allowance.
* @param dest Destination address.
*/
function safeTransferAssetFromCalldata(Asset memory asset, address source, address dest, bool fromSender) pure internal returns (bytes memory) {
return _transferAssetFromCalldata(asset, source, dest, fromSender, true);
}
function _transferAssetFromCalldata(Asset memory asset, address source, address dest, bool fromSender, bool isSafe) pure private returns (bytes memory) {
if (asset.category == Category.ERC20) {
if (fromSender) {
return abi.encodeWithSignature(
"transfer(address,uint256)", dest, asset.amount
);
} else {
return abi.encodeWithSignature(
"transferFrom(address,address,uint256)", source, dest, asset.amount
);
}
} else if (asset.category == Category.ERC721) {
if (!isSafe) {
return abi.encodeWithSignature(
"transferFrom(address,address,uint256)", source, dest, asset.id
);
} else {
return abi.encodeWithSignature(
"safeTransferFrom(address,address,uint256,bytes)", source, dest, asset.id, ""
);
}
} else if (asset.category == Category.ERC1155) {
return abi.encodeWithSignature(
"safeTransferFrom(address,address,uint256,uint256,bytes)", source, dest, asset.id, asset.amount == 0 ? 1 : asset.amount, ""
);
} else if (asset.category == Category.CryptoKitties) {
if (fromSender) {
return abi.encodeWithSignature(
"transfer(address,uint256)", dest, asset.id
);
} else {
return abi.encodeWithSignature(
"transferFrom(address,address,uint256)", source, dest, asset.id
);
}
} else {
revert("MultiToken: Unsupported category");
}
}
/*----------------------------------------------------------*|
|* # PERMIT *|
|*----------------------------------------------------------*/
/**
* permit
* @dev Wrapping function for granting approval via permit signature.
* @param asset Struct defining all necessary context of a token.
* @param owner Account/address that signed the permit.
* @param spender Account/address that would be granted approval to `asset`.
* @param permitData Data about permit deadline (uint256) and permit signature (64/65 bytes).
* Deadline and signature should be pack encoded together.
* Signature can be standard (65 bytes) or compact (64 bytes) defined in EIP-2098.
*/
function permit(Asset memory asset, address owner, address spender, bytes memory permitData) internal {
if (asset.category == Category.ERC20) {
// Parse deadline and permit signature parameters
uint256 deadline;
bytes32 r;
bytes32 s;
uint8 v;
// Parsing signature parameters used from OpenZeppelins ECDSA library
// https://github.com/OpenZeppelin/openzeppelin-contracts/blob/83277ff916ac4f58fec072b8f28a252c1245c2f1/contracts/utils/cryptography/ECDSA.sol
// Deadline (32 bytes) + standard signature data (65 bytes) -> 97 bytes
if (permitData.length == 97) {
assembly {
deadline := mload(add(permitData, 0x20))
r := mload(add(permitData, 0x40))
s := mload(add(permitData, 0x60))
v := byte(0, mload(add(permitData, 0x80)))
}
}
// Deadline (32 bytes) + compact signature data (64 bytes) -> 96 bytes
else if (permitData.length == 96) {
bytes32 vs;
assembly {
deadline := mload(add(permitData, 0x20))
r := mload(add(permitData, 0x40))
vs := mload(add(permitData, 0x60))
}
s = vs & bytes32(0x7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff);
v = uint8((uint256(vs) >> 255) + 27);
} else {
revert("MultiToken::Permit: Invalid permit length");
}
// Call permit with parsed parameters
IERC20Permit(asset.assetAddress).permit(owner, spender, asset.amount, deadline, v, r, s);
} else {
// Currently supporting only ERC20 signed approvals via ERC2612
revert("MultiToken::Permit: Unsupported category");
}
}
/*----------------------------------------------------------*|
|* # BALANCE OF *|
|*----------------------------------------------------------*/
/**
* balanceOf
* @dev Wrapping function for checking balances on various token interfaces.
* @param asset Struct defining all necessary context of a token.
* @param target Target address to be checked.
*/
function balanceOf(Asset memory asset, address target) internal view returns (uint256) {
if (asset.category == Category.ERC20) {
return IERC20(asset.assetAddress).balanceOf(target);
} else if (asset.category == Category.ERC721) {
return IERC721(asset.assetAddress).ownerOf(asset.id) == target ? 1 : 0;
} else if (asset.category == Category.ERC1155) {
return IERC1155(asset.assetAddress).balanceOf(target, asset.id);
} else if (asset.category == Category.CryptoKitties) {
return ICryptoKitties(asset.assetAddress).ownerOf(asset.id) == target ? 1 : 0;
} else {
revert("MultiToken: Unsupported category");
}
}
/*----------------------------------------------------------*|
|* # APPROVE ASSET *|
|*----------------------------------------------------------*/
/**
* approveAsset
* @dev Wrapping function for `approve` calls on various token interfaces.
* By using `safeApprove` for ERC20, caller can set allowance to 0 or from 0.
* Cannot set non-zero value if allowance is also non-zero.
* @param asset Struct defining all necessary context of a token.
* @param target Account/address that would be granted approval to `asset`.
*/
function approveAsset(Asset memory asset, address target) internal {
if (asset.category == Category.ERC20) {
IERC20(asset.assetAddress).safeApprove(target, asset.amount);
} else if (asset.category == Category.ERC721) {
IERC721(asset.assetAddress).approve(target, asset.id);
} else if (asset.category == Category.ERC1155) {
IERC1155(asset.assetAddress).setApprovalForAll(target, true);
} else if (asset.category == Category.CryptoKitties) {
ICryptoKitties(asset.assetAddress).approve(target, asset.id);
} else {
revert("MultiToken: Unsupported category");
}
}
/*----------------------------------------------------------*|
|* # ASSET CHECKS *|
|*----------------------------------------------------------*/
/**
* isValid
* @dev Checks that provided asset is contract, has correct format and stated category.
* Fungible tokens (ERC20) have to have id = 0.
* NFT (ERC721, CryptoKitties) tokens have to have amount = 0.
* Correct asset category is determined via ERC165.
* The check assumes, that asset contract implements only one token standard at a time.
* @param asset Asset that is examined.
* @return True if assets amount and id is valid in stated category.
*/
function isValid(Asset memory asset) internal view returns (bool) {
if (asset.category == Category.ERC20) {
// Check format
if (asset.id != 0)
return false;
// ERC20 has optional ERC165 implementation
if (asset.assetAddress.supportsERC165()) {
// If ERC20 implements ERC165, it has to return true for its interface id
return asset.assetAddress.supportsERC165InterfaceUnchecked(ERC20_INTERFACE_ID);
} else {
// In case token doesn't implement ERC165, its safe to assume that provided category is correct,
// because any other category have to implement ERC165.
// Check that asset address is contract
// Tip: asset address will return code length 0, if this code is called from the asset constructor
return asset.assetAddress.code.length > 0;
}
} else if (asset.category == Category.ERC721) {
// Check format
if (asset.amount != 0)
return false;
// Check it's ERC721 via ERC165
return asset.assetAddress.supportsInterface(ERC721_INTERFACE_ID);
} else if (asset.category == Category.ERC1155) {
// Check it's ERC1155 via ERC165
return asset.assetAddress.supportsInterface(ERC1155_INTERFACE_ID);
} else if (asset.category == Category.CryptoKitties) {
// Check format
if (asset.amount != 0)
return false;
// Check it's CryptoKitties via ERC165
return asset.assetAddress.supportsInterface(CRYPTO_KITTIES_INTERFACE_ID);
} else {
revert("MultiToken: Unsupported category");
}
}
/**
* isSameAs
* @dev Compare two assets, ignoring their amounts.
* @param asset First asset to examine.
* @param otherAsset Second asset to examine.
* @return True if both structs represents the same asset.
*/
function isSameAs(Asset memory asset, Asset memory otherAsset) internal pure returns (bool) {
return
asset.category == otherAsset.category &&
asset.assetAddress == otherAsset.assetAddress &&
asset.id == otherAsset.id;
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
interface ICryptoKitties {
// Required methods
function totalSupply() external view returns (uint256 total);
function balanceOf(address _owner) external view returns (uint256 balance);
function ownerOf(uint256 _tokenId) external view returns (address owner);
function approve(address _to, uint256 _tokenId) external;
function transfer(address _to, uint256 _tokenId) external;
function transferFrom(address _from, address _to, uint256 _tokenId) external;
// Optional
function name() external view returns (string memory name);
function symbol() external view returns (string memory symbol);
function tokensOfOwner(address _owner) external view returns (uint256[] memory tokenIds);
function tokenMetadata(uint256 _tokenId, string memory _preferredTransport) external view returns (string memory infoUrl);
// Events
event Transfer(address from, address to, uint256 tokenId);
event Approval(address owner, address approved, uint256 tokenId);
// ERC-165 Compatibility (https://github.com/ethereum/EIPs/issues/165)
// Is not part of the interface id
function supportsInterface(bytes4 _interfaceID) external view returns (bool);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)
pragma solidity ^0.8.0;
import "../utils/Context.sol";
/**
* @dev Contract module which provides a basic access control mechanism, where
* there is an account (an owner) that can be granted exclusive access to
* specific functions.
*
* By default, the owner account will be the one that deploys the contract. This
* can later be changed with {transferOwnership}.
*
* This module is used through inheritance. It will make available the modifier
* `onlyOwner`, which can be applied to your functions to restrict their use to
* the owner.
*/
abstract contract Ownable is Context {
address private _owner;
event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);
/**
* @dev Initializes the contract setting the deployer as the initial owner.
*/
constructor() {
_transferOwnership(_msgSender());
}
/**
* @dev Throws if called by any account other than the owner.
*/
modifier onlyOwner() {
_checkOwner();
_;
}
/**
* @dev Returns the address of the current owner.
*/
function owner() public view virtual returns (address) {
return _owner;
}
/**
* @dev Throws if the sender is not the owner.
*/
function _checkOwner() internal view virtual {
require(owner() == _msgSender(), "Ownable: caller is not the owner");
}
/**
* @dev Leaves the contract without owner. It will not be possible to call
* `onlyOwner` functions anymore. Can only be called by the current owner.
*
* NOTE: Renouncing ownership will leave the contract without an owner,
* thereby removing any functionality that is only available to the owner.
*/
function renounceOwnership() public virtual onlyOwner {
_transferOwnership(address(0));
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`).
* Can only be called by the current owner.
*/
function transferOwnership(address newOwner) public virtual onlyOwner {
require(newOwner != address(0), "Ownable: new owner is the zero address");
_transferOwnership(newOwner);
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`).
* Internal function without access restriction.
*/
function _transferOwnership(address newOwner) internal virtual {
address oldOwner = _owner;
_owner = newOwner;
emit OwnershipTransferred(oldOwner, newOwner);
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (access/Ownable2Step.sol)
pragma solidity ^0.8.0;
import "./Ownable.sol";
/**
* @dev Contract module which provides access control mechanism, where
* there is an account (an owner) that can be granted exclusive access to
* specific functions.
*
* By default, the owner account will be the one that deploys the contract. This
* can later be changed with {transferOwnership} and {acceptOwnership}.
*
* This module is used through inheritance. It will make available all functions
* from parent (Ownable).
*/
abstract contract Ownable2Step is Ownable {
address private _pendingOwner;
event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);
/**
* @dev Returns the address of the pending owner.
*/
function pendingOwner() public view virtual returns (address) {
return _pendingOwner;
}
/**
* @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
* Can only be called by the current owner.
*/
function transferOwnership(address newOwner) public virtual override onlyOwner {
_pendingOwner = newOwner;
emit OwnershipTransferStarted(owner(), newOwner);
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
* Internal function without access restriction.
*/
function _transferOwnership(address newOwner) internal virtual override {
delete _pendingOwner;
super._transferOwnership(newOwner);
}
/**
* @dev The new owner accepts the ownership transfer.
*/
function acceptOwnership() external {
address sender = _msgSender();
require(pendingOwner() == sender, "Ownable2Step: caller is not the new owner");
_transferOwnership(sender);
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (interfaces/IERC1155.sol)
pragma solidity ^0.8.0;
import "../token/ERC1155/IERC1155.sol";
<i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (interfaces/IERC20.sol)
pragma solidity ^0.8.0;
import "../token/ERC20/IERC20.sol";
<i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (interfaces/IERC721.sol)
pragma solidity ^0.8.0;
import "../token/ERC721/IERC721.sol";
<i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (proxy/utils/Initializable.sol)
pragma solidity ^0.8.2;
import "../../utils/Address.sol";
/**
* @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
* behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
* external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
* function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
*
* The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
* reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
* case an upgrade adds a module that needs to be initialized.
*
* For example:
*
* [.hljs-theme-light.nopadding]
* ```
* contract MyToken is ERC20Upgradeable {
* function initialize() initializer public {
* __ERC20_init("MyToken", "MTK");
* }
* }
* contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
* function initializeV2() reinitializer(2) public {
* __ERC20Permit_init("MyToken");
* }
* }
* ```
*
* TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
* possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
*
* CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
* that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
*
* [CAUTION]
* ====
* Avoid leaving a contract uninitialized.
*
* An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
* contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
* the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
*
* [.hljs-theme-light.nopadding]
* ```
* /// @custom:oz-upgrades-unsafe-allow constructor
* constructor() {
* _disableInitializers();
* }
* ```
* ====
*/
abstract contract Initializable {
/**
* @dev Indicates that the contract has been initialized.
* @custom:oz-retyped-from bool
*/
uint8 private _initialized;
/**
* @dev Indicates that the contract is in the process of being initialized.
*/
bool private _initializing;
/**
* @dev Triggered when the contract has been initialized or reinitialized.
*/
event Initialized(uint8 version);
/**
* @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
* `onlyInitializing` functions can be used to initialize parent contracts.
*
* Similar to `reinitializer(1)`, except that functions marked with `initializer` can be nested in the context of a
* constructor.
*
* Emits an {Initialized} event.
*/
modifier initializer() {
bool isTopLevelCall = !_initializing;
require(
(isTopLevelCall && _initialized < 1) || (!Address.isContract(address(this)) && _initialized == 1),
"Initializable: contract is already initialized"
);
_initialized = 1;
if (isTopLevelCall) {
_initializing = true;
}
_;
if (isTopLevelCall) {
_initializing = false;
emit Initialized(1);
}
}
/**
* @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
* contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
* used to initialize parent contracts.
*
* A reinitializer may be used after the original initialization step. This is essential to configure modules that
* are added through upgrades and that require initialization.
*
* When `version` is 1, this modifier is similar to `initializer`, except that functions marked with `reinitializer`
* cannot be nested. If one is invoked in the context of another, execution will revert.
*
* Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
* a contract, executing them in the right order is up to the developer or operator.
*
* WARNING: setting the version to 255 will prevent any future reinitialization.
*
* Emits an {Initialized} event.
*/
modifier reinitializer(uint8 version) {
require(!_initializing && _initialized < version, "Initializable: contract is already initialized");
_initialized = version;
_initializing = true;
_;
_initializing = false;
emit Initialized(version);
}
/**
* @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
* {initializer} and {reinitializer} modifiers, directly or indirectly.
*/
modifier onlyInitializing() {
require(_initializing, "Initializable: contract is not initializing");
_;
}
/**
* @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
* Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
* to any version. It is recommended to use this to lock implementation contracts that are designed to be called
* through proxies.
*
* Emits an {Initialized} event the first time it is successfully executed.
*/
function _disableInitializers() internal virtual {
require(!_initializing, "Initializable: contract is initializing");
if (_initialized < type(uint8).max) {
_initialized = type(uint8).max;
emit Initialized(type(uint8).max);
}
}
/**
* @dev Returns the highest version that has been initialized. See {reinitializer}.
*/
function _getInitializedVersion() internal view returns (uint8) {
return _initialized;
}
/**
* @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
*/
function _isInitializing() internal view returns (bool) {
return _initializing;
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (token/ERC1155/IERC1155.sol)
pragma solidity ^0.8.0;
import "../../utils/introspection/IERC165.sol";
/**
* @dev Required interface of an ERC1155 compliant contract, as defined in the
* https://eips.ethereum.org/EIPS/eip-1155[EIP].
*
* _Available since v3.1._
*/
interface IERC1155 is IERC165 {
/**
* @dev Emitted when `value` tokens of token type `id` are transferred from `from` to `to` by `operator`.
*/
event TransferSingle(address indexed operator, address indexed from, address indexed to, uint256 id, uint256 value);
/**
* @dev Equivalent to multiple {TransferSingle} events, where `operator`, `from` and `to` are the same for all
* transfers.
*/
event TransferBatch(
address indexed operator,
address indexed from,
address indexed to,
uint256[] ids,
uint256[] values
);
/**
* @dev Emitted when `account` grants or revokes permission to `operator` to transfer their tokens, according to
* `approved`.
*/
event ApprovalForAll(address indexed account, address indexed operator, bool approved);
/**
* @dev Emitted when the URI for token type `id` changes to `value`, if it is a non-programmatic URI.
*
* If an {URI} event was emitted for `id`, the standard
* https://eips.ethereum.org/EIPS/eip-1155#metadata-extensions[guarantees] that `value` will equal the value
* returned by {IERC1155MetadataURI-uri}.
*/
event URI(string value, uint256 indexed id);
/**
* @dev Returns the amount of tokens of token type `id` owned by `account`.
*
* Requirements:
*
* - `account` cannot be the zero address.
*/
function balanceOf(address account, uint256 id) external view returns (uint256);
/**
* @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {balanceOf}.
*
* Requirements:
*
* - `accounts` and `ids` must have the same length.
*/
function balanceOfBatch(address[] calldata accounts, uint256[] calldata ids)
external
view
returns (uint256[] memory);
/**
* @dev Grants or revokes permission to `operator` to transfer the caller's tokens, according to `approved`,
*
* Emits an {ApprovalForAll} event.
*
* Requirements:
*
* - `operator` cannot be the caller.
*/
function setApprovalForAll(address operator, bool approved) external;
/**
* @dev Returns true if `operator` is approved to transfer ``account``'s tokens.
*
* See {setApprovalForAll}.
*/
function isApprovedForAll(address account, address operator) external view returns (bool);
/**
* @dev Transfers `amount` tokens of token type `id` from `from` to `to`.
*
* Emits a {TransferSingle} event.
*
* Requirements:
*
* - `to` cannot be the zero address.
* - If the caller is not `from`, it must have been approved to spend ``from``'s tokens via {setApprovalForAll}.
* - `from` must have a balance of tokens of type `id` of at least `amount`.
* - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155Received} and return the
* acceptance magic value.
*/
function safeTransferFrom(
address from,
address to,
uint256 id,
uint256 amount,
bytes calldata data
) external;
/**
* @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {safeTransferFrom}.
*
* Emits a {TransferBatch} event.
*
* Requirements:
*
* - `ids` and `amounts` must have the same length.
* - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155BatchReceived} and return the
* acceptance magic value.
*/
function safeBatchTransferFrom(
address from,
address to,
uint256[] calldata ids,
uint256[] calldata amounts,
bytes calldata data
) external;
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC1155/IERC1155Receiver.sol)
pragma solidity ^0.8.0;
import "../../utils/introspection/IERC165.sol";
/**
* @dev _Available since v3.1._
*/
interface IERC1155Receiver is IERC165 {
/**
* @dev Handles the receipt of a single ERC1155 token type. This function is
* called at the end of a `safeTransferFrom` after the balance has been updated.
*
* NOTE: To accept the transfer, this must return
* `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))`
* (i.e. 0xf23a6e61, or its own function selector).
*
* @param operator The address which initiated the transfer (i.e. msg.sender)
* @param from The address which previously owned the token
* @param id The ID of the token being transferred
* @param value The amount of tokens being transferred
* @param data Additional data with no specified format
* @return `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))` if transfer is allowed
*/
function onERC1155Received(
address operator,
address from,
uint256 id,
uint256 value,
bytes calldata data
) external returns (bytes4);
/**
* @dev Handles the receipt of a multiple ERC1155 token types. This function
* is called at the end of a `safeBatchTransferFrom` after the balances have
* been updated.
*
* NOTE: To accept the transfer(s), this must return
* `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))`
* (i.e. 0xbc197c81, or its own function selector).
*
* @param operator The address which initiated the batch transfer (i.e. msg.sender)
* @param from The address which previously owned the token
* @param ids An array containing ids of each token being transferred (order and length must match values array)
* @param values An array containing amounts of each token being transferred (order and length must match ids array)
* @param data Additional data with no specified format
* @return `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))` if transfer is allowed
*/
function onERC1155BatchReceived(
address operator,
address from,
uint256[] calldata ids,
uint256[] calldata values,
bytes calldata data
) external returns (bytes4);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 standard as defined in the EIP.
*/
interface IERC20 {
/**
* @dev Emitted when `value` tokens are moved from one account (`from`) to
* another (`to`).
*
* Note that `value` may be zero.
*/
event Transfer(address indexed from, address indexed to, uint256 value);
/**
* @dev Emitted when the allowance of a `spender` for an `owner` is set by
* a call to {approve}. `value` is the new allowance.
*/
event Approval(address indexed owner, address indexed spender, uint256 value);
/**
* @dev Returns the amount of tokens in existence.
*/
function totalSupply() external view returns (uint256);
/**
* @dev Returns the amount of tokens owned by `account`.
*/
function balanceOf(address account) external view returns (uint256);
/**
* @dev Moves `amount` tokens from the caller's account to `to`.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transfer(address to, uint256 amount) external returns (bool);
/**
* @dev Returns the remaining number of tokens that `spender` will be
* allowed to spend on behalf of `owner` through {transferFrom}. This is
* zero by default.
*
* This value changes when {approve} or {transferFrom} are called.
*/
function allowance(address owner, address spender) external view returns (uint256);
/**
* @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* IMPORTANT: Beware that changing an allowance with this method brings the risk
* that someone may use both the old and the new allowance by unfortunate
* transaction ordering. One possible solution to mitigate this race
* condition is to first reduce the spender's allowance to 0 and set the
* desired value afterwards:
* https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
*
* Emits an {Approval} event.
*/
function approve(address spender, uint256 amount) external returns (bool);
/**
* @dev Moves `amount` tokens from `from` to `to` using the
* allowance mechanism. `amount` is then deducted from the caller's
* allowance.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transferFrom(
address from,
address to,
uint256 amount
) external returns (bool);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/draft-IERC20Permit.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
* https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
*
* Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
* presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
* need to send a transaction, and thus is not required to hold Ether at all.
*/
interface IERC20Permit {
/**
* @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
* given ``owner``'s signed approval.
*
* IMPORTANT: The same issues {IERC20-approve} has related to transaction
* ordering also apply here.
*
* Emits an {Approval} event.
*
* Requirements:
*
* - `spender` cannot be the zero address.
* - `deadline` must be a timestamp in the future.
* - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
* over the EIP712-formatted function arguments.
* - the signature must use ``owner``'s current nonce (see {nonces}).
*
* For more information on the signature format, see the
* https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
* section].
*/
function permit(
address owner,
address spender,
uint256 value,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) external;
/**
* @dev Returns the current nonce for `owner`. This value must be
* included whenever a signature is generated for {permit}.
*
* Every successful call to {permit} increases ``owner``'s nonce by one. This
* prevents a signature from being used multiple times.
*/
function nonces(address owner) external view returns (uint256);
/**
* @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
*/
// solhint-disable-next-line func-name-mixedcase
function DOMAIN_SEPARATOR() external view returns (bytes32);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/utils/SafeERC20.sol)
pragma solidity ^0.8.0;
import "../IERC20.sol";
import "../extensions/draft-IERC20Permit.sol";
import "../../../utils/Address.sol";
/**
* @title SafeERC20
* @dev Wrappers around ERC20 operations that throw on failure (when the token
* contract returns false). Tokens that return no value (and instead revert or
* throw on failure) are also supported, non-reverting calls are assumed to be
* successful.
* To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
* which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
*/
library SafeERC20 {
using Address for address;
function safeTransfer(
IERC20 token,
address to,
uint256 value
) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
}
function safeTransferFrom(
IERC20 token,
address from,
address to,
uint256 value
) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
}
/**
* @dev Deprecated. This function has issues similar to the ones found in
* {IERC20-approve}, and its usage is discouraged.
*
* Whenever possible, use {safeIncreaseAllowance} and
* {safeDecreaseAllowance} instead.
*/
function safeApprove(
IERC20 token,
address spender,
uint256 value
) internal {
// safeApprove should only be called when setting an initial allowance,
// or when resetting it to zero. To increase and decrease it, use
// 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
require(
(value == 0) || (token.allowance(address(this), spender) == 0),
"SafeERC20: approve from non-zero to non-zero allowance"
);
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
}
function safeIncreaseAllowance(
IERC20 token,
address spender,
uint256 value
) internal {
uint256 newAllowance = token.allowance(address(this), spender) + value;
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
}
function safeDecreaseAllowance(
IERC20 token,
address spender,
uint256 value
) internal {
unchecked {
uint256 oldAllowance = token.allowance(address(this), spender);
require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
uint256 newAllowance = oldAllowance - value;
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
}
}
function safePermit(
IERC20Permit token,
address owner,
address spender,
uint256 value,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) internal {
uint256 nonceBefore = token.nonces(owner);
token.permit(owner, spender, value, deadline, v, r, s);
uint256 nonceAfter = token.nonces(owner);
require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
}
/**
* @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
* on the return value: the return value is optional (but if data is returned, it must not be false).
* @param token The token targeted by the call.
* @param data The call data (encoded using abi.encode or one of its variants).
*/
function _callOptionalReturn(IERC20 token, bytes memory data) private {
// We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
// we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
// the target address contains contract code and also asserts for success in the low-level call.
bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
if (returndata.length > 0) {
// Return data is optional
require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
}
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC721/ERC721.sol)
pragma solidity ^0.8.0;
import "./IERC721.sol";
import "./IERC721Receiver.sol";
import "./extensions/IERC721Metadata.sol";
import "../../utils/Address.sol";
import "../../utils/Context.sol";
import "../../utils/Strings.sol";
import "../../utils/introspection/ERC165.sol";
/**
* @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
* the Metadata extension, but not including the Enumerable extension, which is available separately as
* {ERC721Enumerable}.
*/
contract ERC721 is Context, ERC165, IERC721, IERC721Metadata {
using Address for address;
using Strings for uint256;
// Token name
string private _name;
// Token symbol
string private _symbol;
// Mapping from token ID to owner address
mapping(uint256 => address) private _owners;
// Mapping owner address to token count
mapping(address => uint256) private _balances;
// Mapping from token ID to approved address
mapping(uint256 => address) private _tokenApprovals;
// Mapping from owner to operator approvals
mapping(address => mapping(address => bool)) private _operatorApprovals;
/**
* @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
*/
constructor(string memory name_, string memory symbol_) {
_name = name_;
_symbol = symbol_;
}
/**
* @dev See {IERC165-supportsInterface}.
*/
function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
return
interfaceId == type(IERC721).interfaceId ||
interfaceId == type(IERC721Metadata).interfaceId ||
super.supportsInterface(interfaceId);
}
/**
* @dev See {IERC721-balanceOf}.
*/
function balanceOf(address owner) public view virtual override returns (uint256) {
require(owner != address(0), "ERC721: address zero is not a valid owner");
return _balances[owner];
}
/**
* @dev See {IERC721-ownerOf}.
*/
function ownerOf(uint256 tokenId) public view virtual override returns (address) {
address owner = _ownerOf(tokenId);
require(owner != address(0), "ERC721: invalid token ID");
return owner;
}
/**
* @dev See {IERC721Metadata-name}.
*/
function name() public view virtual override returns (string memory) {
return _name;
}
/**
* @dev See {IERC721Metadata-symbol}.
*/
function symbol() public view virtual override returns (string memory) {
return _symbol;
}
/**
* @dev See {IERC721Metadata-tokenURI}.
*/
function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
_requireMinted(tokenId);
string memory baseURI = _baseURI();
return bytes(baseURI).length > 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : "";
}
/**
* @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
* token will be the concatenation of the `baseURI` and the `tokenId`. Empty
* by default, can be overridden in child contracts.
*/
function _baseURI() internal view virtual returns (string memory) {
return "";
}
/**
* @dev See {IERC721-approve}.
*/
function approve(address to, uint256 tokenId) public virtual override {
address owner = ERC721.ownerOf(tokenId);
require(to != owner, "ERC721: approval to current owner");
require(
_msgSender() == owner || isApprovedForAll(owner, _msgSender()),
"ERC721: approve caller is not token owner or approved for all"
);
_approve(to, tokenId);
}
/**
* @dev See {IERC721-getApproved}.
*/
function getApproved(uint256 tokenId) public view virtual override returns (address) {
_requireMinted(tokenId);
return _tokenApprovals[tokenId];
}
/**
* @dev See {IERC721-setApprovalForAll}.
*/
function setApprovalForAll(address operator, bool approved) public virtual override {
_setApprovalForAll(_msgSender(), operator, approved);
}
/**
* @dev See {IERC721-isApprovedForAll}.
*/
function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
return _operatorApprovals[owner][operator];
}
/**
* @dev See {IERC721-transferFrom}.
*/
function transferFrom(
address from,
address to,
uint256 tokenId
) public virtual override {
//solhint-disable-next-line max-line-length
require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: caller is not token owner or approved");
_transfer(from, to, tokenId);
}
/**
* @dev See {IERC721-safeTransferFrom}.
*/
function safeTransferFrom(
address from,
address to,
uint256 tokenId
) public virtual override {
safeTransferFrom(from, to, tokenId, "");
}
/**
* @dev See {IERC721-safeTransferFrom}.
*/
function safeTransferFrom(
address from,
address to,
uint256 tokenId,
bytes memory data
) public virtual override {
require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: caller is not token owner or approved");
_safeTransfer(from, to, tokenId, data);
}
/**
* @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
* are aware of the ERC721 protocol to prevent tokens from being forever locked.
*
* `data` is additional data, it has no specified format and it is sent in call to `to`.
*
* This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
* implement alternative mechanisms to perform token transfer, such as signature-based.
*
* Requirements:
*
* - `from` cannot be the zero address.
* - `to` cannot be the zero address.
* - `tokenId` token must exist and be owned by `from`.
* - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
*
* Emits a {Transfer} event.
*/
function _safeTransfer(
address from,
address to,
uint256 tokenId,
bytes memory data
) internal virtual {
_transfer(from, to, tokenId);
require(_checkOnERC721Received(from, to, tokenId, data), "ERC721: transfer to non ERC721Receiver implementer");
}
/**
* @dev Returns the owner of the `tokenId`. Does NOT revert if token doesn't exist
*/
function _ownerOf(uint256 tokenId) internal view virtual returns (address) {
return _owners[tokenId];
}
/**
* @dev Returns whether `tokenId` exists.
*
* Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
*
* Tokens start existing when they are minted (`_mint`),
* and stop existing when they are burned (`_burn`).
*/
function _exists(uint256 tokenId) internal view virtual returns (bool) {
return _ownerOf(tokenId) != address(0);
}
/**
* @dev Returns whether `spender` is allowed to manage `tokenId`.
*
* Requirements:
*
* - `tokenId` must exist.
*/
function _isApprovedOrOwner(address spender, uint256 tokenId) internal view virtual returns (bool) {
address owner = ERC721.ownerOf(tokenId);
return (spender == owner || isApprovedForAll(owner, spender) || getApproved(tokenId) == spender);
}
/**
* @dev Safely mints `tokenId` and transfers it to `to`.
*
* Requirements:
*
* - `tokenId` must not exist.
* - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
*
* Emits a {Transfer} event.
*/
function _safeMint(address to, uint256 tokenId) internal virtual {
_safeMint(to, tokenId, "");
}
/**
* @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
* forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
*/
function _safeMint(
address to,
uint256 tokenId,
bytes memory data
) internal virtual {
_mint(to, tokenId);
require(
_checkOnERC721Received(address(0), to, tokenId, data),
"ERC721: transfer to non ERC721Receiver implementer"
);
}
/**
* @dev Mints `tokenId` and transfers it to `to`.
*
* WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
*
* Requirements:
*
* - `tokenId` must not exist.
* - `to` cannot be the zero address.
*
* Emits a {Transfer} event.
*/
function _mint(address to, uint256 tokenId) internal virtual {
require(to != address(0), "ERC721: mint to the zero address");
require(!_exists(tokenId), "ERC721: token already minted");
_beforeTokenTransfer(address(0), to, tokenId, 1);
// Check that tokenId was not minted by `_beforeTokenTransfer` hook
require(!_exists(tokenId), "ERC721: token already minted");
unchecked {
// Will not overflow unless all 2**256 token ids are minted to the same owner.
// Given that tokens are minted one by one, it is impossible in practice that
// this ever happens. Might change if we allow batch minting.
// The ERC fails to describe this case.
_balances[to] += 1;
}
_owners[tokenId] = to;
emit Transfer(address(0), to, tokenId);
_afterTokenTransfer(address(0), to, tokenId, 1);
}
/**
* @dev Destroys `tokenId`.
* The approval is cleared when the token is burned.
* This is an internal function that does not check if the sender is authorized to operate on the token.
*
* Requirements:
*
* - `tokenId` must exist.
*
* Emits a {Transfer} event.
*/
function _burn(uint256 tokenId) internal virtual {
address owner = ERC721.ownerOf(tokenId);
_beforeTokenTransfer(owner, address(0), tokenId, 1);
// Update ownership in case tokenId was transferred by `_beforeTokenTransfer` hook
owner = ERC721.ownerOf(tokenId);
// Clear approvals
delete _tokenApprovals[tokenId];
unchecked {
// Cannot overflow, as that would require more tokens to be burned/transferred
// out than the owner initially received through minting and transferring in.
_balances[owner] -= 1;
}
delete _owners[tokenId];
emit Transfer(owner, address(0), tokenId);
_afterTokenTransfer(owner, address(0), tokenId, 1);
}
/**
* @dev Transfers `tokenId` from `from` to `to`.
* As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
*
* Requirements:
*
* - `to` cannot be the zero address.
* - `tokenId` token must be owned by `from`.
*
* Emits a {Transfer} event.
*/
function _transfer(
address from,
address to,
uint256 tokenId
) internal virtual {
require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer from incorrect owner");
require(to != address(0), "ERC721: transfer to the zero address");
_beforeTokenTransfer(from, to, tokenId, 1);
// Check that tokenId was not transferred by `_beforeTokenTransfer` hook
require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer from incorrect owner");
// Clear approvals from the previous owner
delete _tokenApprovals[tokenId];
unchecked {
// `_balances[from]` cannot overflow for the same reason as described in `_burn`:
// `from`'s balance is the number of token held, which is at least one before the current
// transfer.
// `_balances[to]` could overflow in the conditions described in `_mint`. That would require
// all 2**256 token ids to be minted, which in practice is impossible.
_balances[from] -= 1;
_balances[to] += 1;
}
_owners[tokenId] = to;
emit Transfer(from, to, tokenId);
_afterTokenTransfer(from, to, tokenId, 1);
}
/**
* @dev Approve `to` to operate on `tokenId`
*
* Emits an {Approval} event.
*/
function _approve(address to, uint256 tokenId) internal virtual {
_tokenApprovals[tokenId] = to;
emit Approval(ERC721.ownerOf(tokenId), to, tokenId);
}
/**
* @dev Approve `operator` to operate on all of `owner` tokens
*
* Emits an {ApprovalForAll} event.
*/
function _setApprovalForAll(
address owner,
address operator,
bool approved
) internal virtual {
require(owner != operator, "ERC721: approve to caller");
_operatorApprovals[owner][operator] = approved;
emit ApprovalForAll(owner, operator, approved);
}
/**
* @dev Reverts if the `tokenId` has not been minted yet.
*/
function _requireMinted(uint256 tokenId) internal view virtual {
require(_exists(tokenId), "ERC721: invalid token ID");
}
/**
* @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
* The call is not executed if the target address is not a contract.
*
* @param from address representing the previous owner of the given token ID
* @param to target address that will receive the tokens
* @param tokenId uint256 ID of the token to be transferred
* @param data bytes optional data to send along with the call
* @return bool whether the call correctly returned the expected magic value
*/
function _checkOnERC721Received(
address from,
address to,
uint256 tokenId,
bytes memory data
) private returns (bool) {
if (to.isContract()) {
try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, data) returns (bytes4 retval) {
return retval == IERC721Receiver.onERC721Received.selector;
} catch (bytes memory reason) {
if (reason.length == 0) {
revert("ERC721: transfer to non ERC721Receiver implementer");
} else {
/// @solidity memory-safe-assembly
assembly {
revert(add(32, reason), mload(reason))
}
}
}
} else {
return true;
}
}
/**
* @dev Hook that is called before any token transfer. This includes minting and burning. If {ERC721Consecutive} is
* used, the hook may be called as part of a consecutive (batch) mint, as indicated by `batchSize` greater than 1.
*
* Calling conditions:
*
* - When `from` and `to` are both non-zero, ``from``'s tokens will be transferred to `to`.
* - When `from` is zero, the tokens will be minted for `to`.
* - When `to` is zero, ``from``'s tokens will be burned.
* - `from` and `to` are never both zero.
* - `batchSize` is non-zero.
*
* To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
*/
function _beforeTokenTransfer(
address from,
address to,
uint256, /* firstTokenId */
uint256 batchSize
) internal virtual {
if (batchSize > 1) {
if (from != address(0)) {
_balances[from] -= batchSize;
}
if (to != address(0)) {
_balances[to] += batchSize;
}
}
}
/**
* @dev Hook that is called after any token transfer. This includes minting and burning. If {ERC721Consecutive} is
* used, the hook may be called as part of a consecutive (batch) mint, as indicated by `batchSize` greater than 1.
*
* Calling conditions:
*
* - When `from` and `to` are both non-zero, ``from``'s tokens were transferred to `to`.
* - When `from` is zero, the tokens were minted for `to`.
* - When `to` is zero, ``from``'s tokens were burned.
* - `from` and `to` are never both zero.
* - `batchSize` is non-zero.
*
* To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
*/
function _afterTokenTransfer(
address from,
address to,
uint256 firstTokenId,
uint256 batchSize
) internal virtual {}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC721/IERC721.sol)
pragma solidity ^0.8.0;
import "../../utils/introspection/IERC165.sol";
/**
* @dev Required interface of an ERC721 compliant contract.
*/
interface IERC721 is IERC165 {
/**
* @dev Emitted when `tokenId` token is transferred from `from` to `to`.
*/
event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);
/**
* @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
*/
event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);
/**
* @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
*/
event ApprovalForAll(address indexed owner, address indexed operator, bool approved);
/**
* @dev Returns the number of tokens in ``owner``'s account.
*/
function balanceOf(address owner) external view returns (uint256 balance);
/**
* @dev Returns the owner of the `tokenId` token.
*
* Requirements:
*
* - `tokenId` must exist.
*/
function ownerOf(uint256 tokenId) external view returns (address owner);
/**
* @dev Safely transfers `tokenId` token from `from` to `to`.
*
* Requirements:
*
* - `from` cannot be the zero address.
* - `to` cannot be the zero address.
* - `tokenId` token must exist and be owned by `from`.
* - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
* - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
*
* Emits a {Transfer} event.
*/
function safeTransferFrom(
address from,
address to,
uint256 tokenId,
bytes calldata data
) external;
/**
* @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
* are aware of the ERC721 protocol to prevent tokens from being forever locked.
*
* Requirements:
*
* - `from` cannot be the zero address.
* - `to` cannot be the zero address.
* - `tokenId` token must exist and be owned by `from`.
* - If the caller is not `from`, it must have been allowed to move this token by either {approve} or {setApprovalForAll}.
* - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
*
* Emits a {Transfer} event.
*/
function safeTransferFrom(
address from,
address to,
uint256 tokenId
) external;
/**
* @dev Transfers `tokenId` token from `from` to `to`.
*
* WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC721
* or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
* understand this adds an external call which potentially creates a reentrancy vulnerability.
*
* Requirements:
*
* - `from` cannot be the zero address.
* - `to` cannot be the zero address.
* - `tokenId` token must be owned by `from`.
* - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
*
* Emits a {Transfer} event.
*/
function transferFrom(
address from,
address to,
uint256 tokenId
) external;
/**
* @dev Gives permission to `to` to transfer `tokenId` token to another account.
* The approval is cleared when the token is transferred.
*
* Only a single account can be approved at a time, so approving the zero address clears previous approvals.
*
* Requirements:
*
* - The caller must own the token or be an approved operator.
* - `tokenId` must exist.
*
* Emits an {Approval} event.
*/
function approve(address to, uint256 tokenId) external;
/**
* @dev Approve or remove `operator` as an operator for the caller.
* Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
*
* Requirements:
*
* - The `operator` cannot be the caller.
*
* Emits an {ApprovalForAll} event.
*/
function setApprovalForAll(address operator, bool _approved) external;
/**
* @dev Returns the account approved for `tokenId` token.
*
* Requirements:
*
* - `tokenId` must exist.
*/
function getApproved(uint256 tokenId) external view returns (address operator);
/**
* @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
*
* See {setApprovalForAll}
*/
function isApprovedForAll(address owner, address operator) external view returns (bool);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC721/IERC721Receiver.sol)
pragma solidity ^0.8.0;
/**
* @title ERC721 token receiver interface
* @dev Interface for any contract that wants to support safeTransfers
* from ERC721 asset contracts.
*/
interface IERC721Receiver {
/**
* @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
* by `operator` from `from`, this function is called.
*
* It must return its Solidity selector to confirm the token transfer.
* If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
*
* The selector can be obtained in Solidity with `IERC721Receiver.onERC721Received.selector`.
*/
function onERC721Received(
address operator,
address from,
uint256 tokenId,
bytes calldata data
) external returns (bytes4);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/extensions/IERC721Metadata.sol)
pragma solidity ^0.8.0;
import "../IERC721.sol";
/**
* @title ERC-721 Non-Fungible Token Standard, optional metadata extension
* @dev See https://eips.ethereum.org/EIPS/eip-721
*/
interface IERC721Metadata is IERC721 {
/**
* @dev Returns the token collection name.
*/
function name() external view returns (string memory);
/**
* @dev Returns the token collection symbol.
*/
function symbol() external view returns (string memory);
/**
* @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
*/
function tokenURI(uint256 tokenId) external view returns (string memory);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Address.sol)
pragma solidity ^0.8.1;
/**
* @dev Collection of functions related to the address type
*/
library Address {
/**
* @dev Returns true if `account` is a contract.
*
* [IMPORTANT]
* ====
* It is unsafe to assume that an address for which this function returns
* false is an externally-owned account (EOA) and not a contract.
*
* Among others, `isContract` will return false for the following
* types of addresses:
*
* - an externally-owned account
* - a contract in construction
* - an address where a contract will be created
* - an address where a contract lived, but was destroyed
* ====
*
* [IMPORTANT]
* ====
* You shouldn't rely on `isContract` to protect against flash loan attacks!
*
* Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
* like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
* constructor.
* ====
*/
function isContract(address account) internal view returns (bool) {
// This method relies on extcodesize/address.code.length, which returns 0
// for contracts in construction, since the code is only stored at the end
// of the constructor execution.
return account.code.length > 0;
}
/**
* @dev Replacement for Solidity's `transfer`: sends `amount` wei to
* `recipient`, forwarding all available gas and reverting on errors.
*
* https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
* of certain opcodes, possibly making contracts go over the 2300 gas limit
* imposed by `transfer`, making them unable to receive funds via
* `transfer`. {sendValue} removes this limitation.
*
* https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
*
* IMPORTANT: because control is transferred to `recipient`, care must be
* taken to not create reentrancy vulnerabilities. Consider using
* {ReentrancyGuard} or the
* https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
*/
function sendValue(address payable recipient, uint256 amount) internal {
require(address(this).balance >= amount, "Address: insufficient balance");
(bool success, ) = recipient.call{value: amount}("");
require(success, "Address: unable to send value, recipient may have reverted");
}
/**
* @dev Performs a Solidity function call using a low level `call`. A
* plain `call` is an unsafe replacement for a function call: use this
* function instead.
*
* If `target` reverts with a revert reason, it is bubbled up by this
* function (like regular Solidity function calls).
*
* Returns the raw returned data. To convert to the expected return value,
* use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
*
* Requirements:
*
* - `target` must be a contract.
* - calling `target` with `data` must not revert.
*
* _Available since v3.1._
*/
function functionCall(address target, bytes memory data) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, "Address: low-level call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
* `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but also transferring `value` wei to `target`.
*
* Requirements:
*
* - the calling contract must have an ETH balance of at least `value`.
* - the called Solidity function must be `payable`.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value
) internal returns (bytes memory) {
return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
}
/**
* @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
* with `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value,
string memory errorMessage
) internal returns (bytes memory) {
require(address(this).balance >= value, "Address: insufficient balance for call");
(bool success, bytes memory returndata) = target.call{value: value}(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
return functionStaticCall(target, data, "Address: low-level static call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(
address target,
bytes memory data,
string memory errorMessage
) internal view returns (bytes memory) {
(bool success, bytes memory returndata) = target.staticcall(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
return functionDelegateCall(target, data, "Address: low-level delegate call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
(bool success, bytes memory returndata) = target.delegatecall(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
* the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
*
* _Available since v4.8._
*/
function verifyCallResultFromTarget(
address target,
bool success,
bytes memory returndata,
string memory errorMessage
) internal view returns (bytes memory) {
if (success) {
if (returndata.length == 0) {
// only check isContract if the call was successful and the return data is empty
// otherwise we already know that it was a contract
require(isContract(target), "Address: call to non-contract");
}
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
/**
* @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
* revert reason or using the provided one.
*
* _Available since v4.3._
*/
function verifyCallResult(
bool success,
bytes memory returndata,
string memory errorMessage
) internal pure returns (bytes memory) {
if (success) {
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
function _revert(bytes memory returndata, string memory errorMessage) private pure {
// Look for revert reason and bubble it up if present
if (returndata.length > 0) {
// The easiest way to bubble the revert reason is using memory via assembly
/// @solidity memory-safe-assembly
assembly {
let returndata_size := mload(returndata)
revert(add(32, returndata), returndata_size)
}
} else {
revert(errorMessage);
}
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)
pragma solidity ^0.8.0;
/**
* @dev Provides information about the current execution context, including the
* sender of the transaction and its data. While these are generally available
* via msg.sender and msg.data, they should not be accessed in such a direct
* manner, since when dealing with meta-transactions the account sending and
* paying for execution may not be the actual sender (as far as an application
* is concerned).
*
* This contract is only required for intermediate, library-like contracts.
*/
abstract contract Context {
function _msgSender() internal view virtual returns (address) {
return msg.sender;
}
function _msgData() internal view virtual returns (bytes calldata) {
return msg.data;
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Strings.sol)
pragma solidity ^0.8.0;
import "./math/Math.sol";
/**
* @dev String operations.
*/
library Strings {
bytes16 private constant _SYMBOLS = "0123456789abcdef";
uint8 private constant _ADDRESS_LENGTH = 20;
/**
* @dev Converts a `uint256` to its ASCII `string` decimal representation.
*/
function toString(uint256 value) internal pure returns (string memory) {
unchecked {
uint256 length = Math.log10(value) + 1;
string memory buffer = new string(length);
uint256 ptr;
/// @solidity memory-safe-assembly
assembly {
ptr := add(buffer, add(32, length))
}
while (true) {
ptr--;
/// @solidity memory-safe-assembly
assembly {
mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
}
value /= 10;
if (value == 0) break;
}
return buffer;
}
}
/**
* @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
*/
function toHexString(uint256 value) internal pure returns (string memory) {
unchecked {
return toHexString(value, Math.log256(value) + 1);
}
}
/**
* @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
*/
function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
bytes memory buffer = new bytes(2 * length + 2);
buffer[0] = "0";
buffer[1] = "x";
for (uint256 i = 2 * length + 1; i > 1; --i) {
buffer[i] = _SYMBOLS[value & 0xf];
value >>= 4;
}
require(value == 0, "Strings: hex length insufficient");
return string(buffer);
}
/**
* @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
*/
function toHexString(address addr) internal pure returns (string memory) {
return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)
pragma solidity ^0.8.0;
import "./IERC165.sol";
/**
* @dev Implementation of the {IERC165} interface.
*
* Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
* for the additional interface id that will be supported. For example:
*
* ```solidity
* function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
* return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
* }
* ```
*
* Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
*/
abstract contract ERC165 is IERC165 {
/**
* @dev See {IERC165-supportsInterface}.
*/
function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
return interfaceId == type(IERC165).interfaceId;
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/introspection/ERC165Checker.sol)
pragma solidity ^0.8.0;
import "./IERC165.sol";
/**
* @dev Library used to query support of an interface declared via {IERC165}.
*
* Note that these functions return the actual result of the query: they do not
* `revert` if an interface is not supported. It is up to the caller to decide
* what to do in these cases.
*/
library ERC165Checker {
// As per the EIP-165 spec, no interface should ever match 0xffffffff
bytes4 private constant _INTERFACE_ID_INVALID = 0xffffffff;
/**
* @dev Returns true if `account` supports the {IERC165} interface.
*/
function supportsERC165(address account) internal view returns (bool) {
// Any contract that implements ERC165 must explicitly indicate support of
// InterfaceId_ERC165 and explicitly indicate non-support of InterfaceId_Invalid
return
supportsERC165InterfaceUnchecked(account, type(IERC165).interfaceId) &&
!supportsERC165InterfaceUnchecked(account, _INTERFACE_ID_INVALID);
}
/**
* @dev Returns true if `account` supports the interface defined by
* `interfaceId`. Support for {IERC165} itself is queried automatically.
*
* See {IERC165-supportsInterface}.
*/
function supportsInterface(address account, bytes4 interfaceId) internal view returns (bool) {
// query support of both ERC165 as per the spec and support of _interfaceId
return supportsERC165(account) && supportsERC165InterfaceUnchecked(account, interfaceId);
}
/**
* @dev Returns a boolean array where each value corresponds to the
* interfaces passed in and whether they're supported or not. This allows
* you to batch check interfaces for a contract where your expectation
* is that some interfaces may not be supported.
*
* See {IERC165-supportsInterface}.
*
* _Available since v3.4._
*/
function getSupportedInterfaces(address account, bytes4[] memory interfaceIds)
internal
view
returns (bool[] memory)
{
// an array of booleans corresponding to interfaceIds and whether they're supported or not
bool[] memory interfaceIdsSupported = new bool[](interfaceIds.length);
// query support of ERC165 itself
if (supportsERC165(account)) {
// query support of each interface in interfaceIds
for (uint256 i = 0; i < interfaceIds.length; i++) {
interfaceIdsSupported[i] = supportsERC165InterfaceUnchecked(account, interfaceIds[i]);
}
}
return interfaceIdsSupported;
}
/**
* @dev Returns true if `account` supports all the interfaces defined in
* `interfaceIds`. Support for {IERC165} itself is queried automatically.
*
* Batch-querying can lead to gas savings by skipping repeated checks for
* {IERC165} support.
*
* See {IERC165-supportsInterface}.
*/
function supportsAllInterfaces(address account, bytes4[] memory interfaceIds) internal view returns (bool) {
// query support of ERC165 itself
if (!supportsERC165(account)) {
return false;
}
// query support of each interface in interfaceIds
for (uint256 i = 0; i < interfaceIds.length; i++) {
if (!supportsERC165InterfaceUnchecked(account, interfaceIds[i])) {
return false;
}
}
// all interfaces supported
return true;
}
/**
* @notice Query if a contract implements an interface, does not check ERC165 support
* @param account The address of the contract to query for support of an interface
* @param interfaceId The interface identifier, as specified in ERC-165
* @return true if the contract at account indicates support of the interface with
* identifier interfaceId, false otherwise
* @dev Assumes that account contains a contract that supports ERC165, otherwise
* the behavior of this method is undefined. This precondition can be checked
* with {supportsERC165}.
* Interface identification is specified in ERC-165.
*/
function supportsERC165InterfaceUnchecked(address account, bytes4 interfaceId) internal view returns (bool) {
// prepare call
bytes memory encodedParams = abi.encodeWithSelector(IERC165.supportsInterface.selector, interfaceId);
// perform static call
bool success;
uint256 returnSize;
uint256 returnValue;
assembly {
success := staticcall(30000, account, add(encodedParams, 0x20), mload(encodedParams), 0x00, 0x20)
returnSize := returndatasize()
returnValue := mload(0x00)
}
return success && returnSize >= 0x20 && returnValue > 0;
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC165 standard, as defined in the
* https://eips.ethereum.org/EIPS/eip-165[EIP].
*
* Implementers can declare support of contract interfaces, which can then be
* queried by others ({ERC165Checker}).
*
* For an implementation, see {ERC165}.
*/
interface IERC165 {
/**
* @dev Returns true if this contract implements the interface defined by
* `interfaceId`. See the corresponding
* https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
* to learn more about how these ids are created.
*
* This function call must use less than 30 000 gas.
*/
function supportsInterface(bytes4 interfaceId) external view returns (bool);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/Math.sol)
pragma solidity ^0.8.0;
/**
* @dev Standard math utilities missing in the Solidity language.
*/
library Math {
enum Rounding {
Down, // Toward negative infinity
Up, // Toward infinity
Zero // Toward zero
}
/**
* @dev Returns the largest of two numbers.
*/
function max(uint256 a, uint256 b) internal pure returns (uint256) {
return a > b ? a : b;
}
/**
* @dev Returns the smallest of two numbers.
*/
function min(uint256 a, uint256 b) internal pure returns (uint256) {
return a < b ? a : b;
}
/**
* @dev Returns the average of two numbers. The result is rounded towards
* zero.
*/
function average(uint256 a, uint256 b) internal pure returns (uint256) {
// (a + b) / 2 can overflow.
return (a & b) + (a ^ b) / 2;
}
/**
* @dev Returns the ceiling of the division of two numbers.
*
* This differs from standard division with `/` in that it rounds up instead
* of rounding down.
*/
function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
// (a + b - 1) / b can overflow on addition, so we distribute.
return a == 0 ? 0 : (a - 1) / b + 1;
}
/**
* @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
* @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
* with further edits by Uniswap Labs also under MIT license.
*/
function mulDiv(
uint256 x,
uint256 y,
uint256 denominator
) internal pure returns (uint256 result) {
unchecked {
// 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
// use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
// variables such that product = prod1 * 2^256 + prod0.
uint256 prod0; // Least significant 256 bits of the product
uint256 prod1; // Most significant 256 bits of the product
assembly {
let mm := mulmod(x, y, not(0))
prod0 := mul(x, y)
prod1 := sub(sub(mm, prod0), lt(mm, prod0))
}
// Handle non-overflow cases, 256 by 256 division.
if (prod1 == 0) {
return prod0 / denominator;
}
// Make sure the result is less than 2^256. Also prevents denominator == 0.
require(denominator > prod1);
///////////////////////////////////////////////
// 512 by 256 division.
///////////////////////////////////////////////
// Make division exact by subtracting the remainder from [prod1 prod0].
uint256 remainder;
assembly {
// Compute remainder using mulmod.
remainder := mulmod(x, y, denominator)
// Subtract 256 bit number from 512 bit number.
prod1 := sub(prod1, gt(remainder, prod0))
prod0 := sub(prod0, remainder)
}
// Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
// See https://cs.stackexchange.com/q/138556/92363.
// Does not overflow because the denominator cannot be zero at this stage in the function.
uint256 twos = denominator & (~denominator + 1);
assembly {
// Divide denominator by twos.
denominator := div(denominator, twos)
// Divide [prod1 prod0] by twos.
prod0 := div(prod0, twos)
// Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
twos := add(div(sub(0, twos), twos), 1)
}
// Shift in bits from prod1 into prod0.
prod0 |= prod1 * twos;
// Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
// that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
// four bits. That is, denominator * inv = 1 mod 2^4.
uint256 inverse = (3 * denominator) ^ 2;
// Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
// in modular arithmetic, doubling the correct bits in each step.
inverse *= 2 - denominator * inverse; // inverse mod 2^8
inverse *= 2 - denominator * inverse; // inverse mod 2^16
inverse *= 2 - denominator * inverse; // inverse mod 2^32
inverse *= 2 - denominator * inverse; // inverse mod 2^64
inverse *= 2 - denominator * inverse; // inverse mod 2^128
inverse *= 2 - denominator * inverse; // inverse mod 2^256
// Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
// This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
// less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
// is no longer required.
result = prod0 * inverse;
return result;
}
}
/**
* @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
*/
function mulDiv(
uint256 x,
uint256 y,
uint256 denominator,
Rounding rounding
) internal pure returns (uint256) {
uint256 result = mulDiv(x, y, denominator);
if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
result += 1;
}
return result;
}
/**
* @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
*
* Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
*/
function sqrt(uint256 a) internal pure returns (uint256) {
if (a == 0) {
return 0;
}
// For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
//
// We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
// `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
//
// This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
// → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
// → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
//
// Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
uint256 result = 1 << (log2(a) >> 1);
// At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
// since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
// every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
// into the expected uint128 result.
unchecked {
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
return min(result, a / result);
}
}
/**
* @notice Calculates sqrt(a), following the selected rounding direction.
*/
function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
unchecked {
uint256 result = sqrt(a);
return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
}
}
/**
* @dev Return the log in base 2, rounded down, of a positive value.
* Returns 0 if given 0.
*/
function log2(uint256 value) internal pure returns (uint256) {
uint256 result = 0;
unchecked {
if (value >> 128 > 0) {
value >>= 128;
result += 128;
}
if (value >> 64 > 0) {
value >>= 64;
result += 64;
}
if (value >> 32 > 0) {
value >>= 32;
result += 32;
}
if (value >> 16 > 0) {
value >>= 16;
result += 16;
}
if (value >> 8 > 0) {
value >>= 8;
result += 8;
}
if (value >> 4 > 0) {
value >>= 4;
result += 4;
}
if (value >> 2 > 0) {
value >>= 2;
result += 2;
}
if (value >> 1 > 0) {
result += 1;
}
}
return result;
}
/**
* @dev Return the log in base 2, following the selected rounding direction, of a positive value.
* Returns 0 if given 0.
*/
function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
unchecked {
uint256 result = log2(value);
return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
}
}
/**
* @dev Return the log in base 10, rounded down, of a positive value.
* Returns 0 if given 0.
*/
function log10(uint256 value) internal pure returns (uint256) {
uint256 result = 0;
unchecked {
if (value >= 10**64) {
value /= 10**64;
result += 64;
}
if (value >= 10**32) {
value /= 10**32;
result += 32;
}
if (value >= 10**16) {
value /= 10**16;
result += 16;
}
if (value >= 10**8) {
value /= 10**8;
result += 8;
}
if (value >= 10**4) {
value /= 10**4;
result += 4;
}
if (value >= 10**2) {
value /= 10**2;
result += 2;
}
if (value >= 10**1) {
result += 1;
}
}
return result;
}
/**
* @dev Return the log in base 10, following the selected rounding direction, of a positive value.
* Returns 0 if given 0.
*/
function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
unchecked {
uint256 result = log10(value);
return result + (rounding == Rounding.Up && 10**result < value ? 1 : 0);
}
}
/**
* @dev Return the log in base 256, rounded down, of a positive value.
* Returns 0 if given 0.
*
* Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
*/
function log256(uint256 value) internal pure returns (uint256) {
uint256 result = 0;
unchecked {
if (value >> 128 > 0) {
value >>= 128;
result += 16;
}
if (value >> 64 > 0) {
value >>= 64;
result += 8;
}
if (value >> 32 > 0) {
value >>= 32;
result += 4;
}
if (value >> 16 > 0) {
value >>= 16;
result += 2;
}
if (value >> 8 > 0) {
result += 1;
}
}
return result;
}
/**
* @dev Return the log in base 10, following the selected rounding direction, of a positive value.
* Returns 0 if given 0.
*/
function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
unchecked {
uint256 result = log256(value);
return result + (rounding == Rounding.Up && 1 << (result * 8) < value ? 1 : 0);
}
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.16;
// Access control
error CallerMissingHubTag(bytes32);
// Loan contract
error LoanDefaulted(uint40);
error InvalidLoanStatus(uint256);
error NonExistingLoan();
error CallerNotLOANTokenHolder();
error InvalidExtendedExpirationDate();
// Invalid asset
error InvalidLoanAsset();
error InvalidCollateralAsset();
// LOAN token
error InvalidLoanContractCaller();
// Vault
error UnsupportedTransferFunction();
error IncompleteTransfer();
// Nonce
error NonceAlreadyRevoked();
error InvalidMinNonce();
// Signature checks
error InvalidSignatureLength(uint256);
error InvalidSignature();
// Offer
error CallerIsNotStatedBorrower(address);
error OfferExpired();
error CollateralIdIsNotWhitelisted();
// Request
error CallerIsNotStatedLender(address);
error RequestExpired();
// Request & Offer
error InvalidDuration();
// Input data
error InvalidInputData();
// Config
error InvalidFeeValue();
error InvalidFeeCollector();
<i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.16;
import "openzeppelin-contracts/contracts/access/Ownable2Step.sol";
import "openzeppelin-contracts/contracts/proxy/utils/Initializable.sol";
import "@pwn/PWNErrors.sol";
/**
* @title PWN Config
* @notice Contract holding configurable values of PWN protocol.
* @dev Is intendet to be used as a proxy via `TransparentUpgradeableProxy`.
*/
contract PWNConfig is Ownable2Step, Initializable {
string internal constant VERSION = "1.0";
/*----------------------------------------------------------*|
|* # VARIABLES & CONSTANTS DEFINITIONS *|
|*----------------------------------------------------------*/
uint16 public constant MAX_FEE = 1000; // 10%
/**
* @notice Protocol fee value in basis points.
* @dev Value of 100 is 1% fee.
*/
uint16 public fee;
/**
* @notice Address that collects protocol fees.
*/
address public feeCollector;
/**
* @notice Mapping of a loan contract address to LOAN token metadata uri.
* @dev LOAN token minted by a loan contract will return metadata uri stored in this mapping.
*/
mapping (address => string) public loanMetadataUri;
/*----------------------------------------------------------*|
|* # EVENTS & ERRORS DEFINITIONS *|
|*----------------------------------------------------------*/
/**
* @dev Emitted when new fee value is set.
*/
event FeeUpdated(uint16 oldFee, uint16 newFee);
/**
* @dev Emitted when new fee collector address is set.
*/
event FeeCollectorUpdated(address oldFeeCollector, address newFeeCollector);
/**
* @dev Emitted when new LOAN token metadata uri is set.
*/
event LoanMetadataUriUpdated(address indexed loanContract, string newUri);
/*----------------------------------------------------------*|
|* # CONSTRUCTOR *|
|*----------------------------------------------------------*/
constructor() Ownable2Step() {
}
function initialize(address _owner, uint16 _fee, address _feeCollector) initializer external {
require(_owner != address(0), "Owner is zero address");
_transferOwnership(_owner);
require(_feeCollector != address(0), "Fee collector is zero address");
_setFeeCollector(_feeCollector);
_setFee(_fee);
}
/*----------------------------------------------------------*|
|* # FEE MANAGEMENT *|
|*----------------------------------------------------------*/
/**
* @notice Set new protocol fee value.
* @dev Only contract owner can call this function.
* @param _fee New fee value in basis points. Value of 100 is 1% fee.
*/
function setFee(uint16 _fee) external onlyOwner {
_setFee(_fee);
}
function _setFee(uint16 _fee) private {
if (_fee > MAX_FEE)
revert InvalidFeeValue();
uint16 oldFee = fee;
fee = _fee;
emit FeeUpdated(oldFee, _fee);
}
/**
* @notice Set new fee collector address.
* @dev Only contract owner can call this function.
* @param _feeCollector New fee collector address.
*/
function setFeeCollector(address _feeCollector) external onlyOwner {
_setFeeCollector(_feeCollector);
}
function _setFeeCollector(address _feeCollector) private {
if (_feeCollector == address(0))
revert InvalidFeeCollector();
address oldFeeCollector = feeCollector;
feeCollector = _feeCollector;
emit FeeCollectorUpdated(oldFeeCollector, _feeCollector);
}
/*----------------------------------------------------------*|
|* # LOAN METADATA MANAGEMENT *|
|*----------------------------------------------------------*/
/**
* @notice Set a LOAN token metadata uri for a specific loan contract.
* @param loanContract Address of a loan contract.
* @param metadataUri New value of LOAN token metadata uri for given `loanContract`.
*/
function setLoanMetadataUri(address loanContract, string memory metadataUri) external onlyOwner {
loanMetadataUri[loanContract] = metadataUri;
emit LoanMetadataUriUpdated(loanContract, metadataUri);
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.16;
import "openzeppelin-contracts/contracts/access/Ownable2Step.sol";
import "@pwn/PWNErrors.sol";
/**
* @title PWN Hub
* @notice Connects PWN contracts together into protocol via tags.
*/
contract PWNHub is Ownable2Step {
/*----------------------------------------------------------*|
|* # VARIABLES & CONSTANTS DEFINITIONS *|
|*----------------------------------------------------------*/
/**
* @dev Mapping of address tags. (contract address => tag => is tagged)
*/
mapping (address => mapping (bytes32 => bool)) private tags;
/*----------------------------------------------------------*|
|* # EVENTS & ERRORS DEFINITIONS *|
|*----------------------------------------------------------*/
/**
* @dev Emitted when tag is set for an address.
*/
event TagSet(address indexed _address, bytes32 indexed tag, bool hasTag);
/*----------------------------------------------------------*|
|* # CONSTRUCTOR *|
|*----------------------------------------------------------*/
constructor() Ownable2Step() {
}
/*----------------------------------------------------------*|
|* # TAG MANAGEMENT *|
|*----------------------------------------------------------*/
/**
* @notice Set tag to an address.
* @dev Tag can be added or removed via this functions. Only callable by contract owner.
* @param _address Address to which a tag is set.
* @param tag Tag that is set to an `_address`.
* @param _hasTag Bool value if tag is added or removed.
*/
function setTag(address _address, bytes32 tag, bool _hasTag) public onlyOwner {
tags[_address][tag] = _hasTag;
emit TagSet(_address, tag, _hasTag);
}
/**
* @notice Set list of tags to an address.
* @dev Tags can be added or removed via this functions. Only callable by contract owner.
* @param _addresses List of addresses to which tags are set.
* @param _tags List of tags that are set to an `_address`.
* @param _hasTag Bool value if tags are added or removed.
*/
function setTags(address[] memory _addresses, bytes32[] memory _tags, bool _hasTag) external onlyOwner {
if (_addresses.length != _tags.length)
revert InvalidInputData();
uint256 length = _tags.length;
for (uint256 i; i < length;) {
setTag(_addresses[i], _tags[i], _hasTag);
unchecked { ++i; }
}
}
/*----------------------------------------------------------*|
|* # TAG GETTER *|
|*----------------------------------------------------------*/
/**
* @dev Return if an address is associated with a tag.
* @param _address Address that is examined for a `tag`.
* @param tag Tag that should an `_address` be associated with.
* @return True if given address has a tag.
*/
function hasTag(address _address, bytes32 tag) external view returns (bool) {
return tags[_address][tag];
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.16;
import "@pwn/hub/PWNHub.sol";
import "@pwn/hub/PWNHubTags.sol";
import "@pwn/PWNErrors.sol";
/**
* @title PWN Hub Access Control
* @notice Implement modifiers for PWN Hub access control.
*/
abstract contract PWNHubAccessControl {
/*----------------------------------------------------------*|
|* # VARIABLES & CONSTANTS DEFINITIONS *|
|*----------------------------------------------------------*/
PWNHub immutable internal hub;
/*----------------------------------------------------------*|
|* # MODIFIERS *|
|*----------------------------------------------------------*/
modifier onlyActiveLoan() {
if (hub.hasTag(msg.sender, PWNHubTags.ACTIVE_LOAN) == false)
revert CallerMissingHubTag(PWNHubTags.ACTIVE_LOAN);
_;
}
modifier onlyWithTag(bytes32 tag) {
if (hub.hasTag(msg.sender, tag) == false)
revert CallerMissingHubTag(tag);
_;
}
/*----------------------------------------------------------*|
|* # CONSTRUCTOR *|
|*----------------------------------------------------------*/
constructor(address pwnHub) {
hub = PWNHub(pwnHub);
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.16;
library PWNHubTags {
string internal constant VERSION = "1.0";
/// @dev Address can mint LOAN tokens and create LOANs via loan factory contracts.
bytes32 internal constant ACTIVE_LOAN = keccak256("PWN_ACTIVE_LOAN");
/// @dev Address can be used as a loan terms factory for creating simple loans.
bytes32 internal constant SIMPLE_LOAN_TERMS_FACTORY = keccak256("PWN_SIMPLE_LOAN_TERMS_FACTORY");
/// @dev Address can revoke loan request nonces.
bytes32 internal constant LOAN_REQUEST = keccak256("PWN_LOAN_REQUEST");
/// @dev Address can revoke loan offer nonces.
bytes32 internal constant LOAN_OFFER = keccak256("PWN_LOAN_OFFER");
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.16;
import "MultiToken/MultiToken.sol";
import "openzeppelin-contracts/contracts/token/ERC721/IERC721Receiver.sol";
import "openzeppelin-contracts/contracts/token/ERC1155/IERC1155Receiver.sol";
import "@pwn/PWNErrors.sol";
/**
* @title PWN Vault
* @notice Base contract for transferring and managing collateral and loan assets in PWN protocol.
* @dev Loan contracts inherits PWN Vault to act as a Vault for its loan type.
*/
abstract contract PWNVault is IERC721Receiver, IERC1155Receiver {
using MultiToken for MultiToken.Asset;
/*----------------------------------------------------------*|
|* # EVENTS DEFINITIONS *|
|*----------------------------------------------------------*/
/**
* @dev Emitted when asset transfer happens from an `origin` address to a vault.
*/
event VaultPull(MultiToken.Asset asset, address indexed origin);
/**
* @dev Emitted when asset transfer happens from a vault to a `beneficiary` address.
*/
event VaultPush(MultiToken.Asset asset, address indexed beneficiary);
/**
* @dev Emitted when asset transfer happens from an `origin` address to a `beneficiary` address.
*/
event VaultPushFrom(MultiToken.Asset asset, address indexed origin, address indexed beneficiary);
/*----------------------------------------------------------*|
|* # TRANSFER FUNCTIONS *|
|*----------------------------------------------------------*/
/**
* pull
* @dev Function accessing an asset and pulling it INTO a vault.
* The function assumes a prior token approval was made to a vault address.
* @param asset An asset construct - for a definition see { MultiToken dependency lib }.
* @param origin Borrower address that is transferring collateral to Vault or repaying a loan.
*/
function _pull(MultiToken.Asset memory asset, address origin) internal {
uint256 originalBalance = asset.balanceOf(address(this));
asset.transferAssetFrom(origin, address(this));
_checkTransfer(asset, originalBalance, address(this));
emit VaultPull(asset, origin);
}
/**
* push
* @dev Function pushing an asset FROM a vault TO a defined recipient.
* This is used for claiming a paid back loan or a defaulted collateral, or returning collateral to a borrower.
* @param asset An asset construct - for a definition see { MultiToken dependency lib }.
* @param beneficiary An address of a recipient of an asset.
*/
function _push(MultiToken.Asset memory asset, address beneficiary) internal {
uint256 originalBalance = asset.balanceOf(beneficiary);
asset.safeTransferAssetFrom(address(this), beneficiary);
_checkTransfer(asset, originalBalance, beneficiary);
emit VaultPush(asset, beneficiary);
}
/**
* pushFrom
* @dev Function pushing an asset FROM a lender TO a borrower.
* The function assumes a prior token approval was made to a vault address.
* @param asset An asset construct - for a definition see { MultiToken dependency lib }.
* @param origin An address of a lender who is providing a loan asset.
* @param beneficiary An address of the recipient of an asset.
*/
function _pushFrom(MultiToken.Asset memory asset, address origin, address beneficiary) internal {
uint256 originalBalance = asset.balanceOf(beneficiary);
asset.safeTransferAssetFrom(origin, beneficiary);
_checkTransfer(asset, originalBalance, beneficiary);
emit VaultPushFrom(asset, origin, beneficiary);
}
function _checkTransfer(MultiToken.Asset memory asset, uint256 originalBalance, address recipient) private view {
if (originalBalance + asset.getTransferAmount() != asset.balanceOf(recipient))
revert IncompleteTransfer();
}
/*----------------------------------------------------------*|
|* # PERMIT *|
|*----------------------------------------------------------*/
/**
* permit
* @dev Function uses signed permit data to set vaults allowance for an asset.
* @param asset An asset construct - for a definition see { MultiToken dependency lib }.
* @param origin An address who is approving an asset.
* @param permit Data about permit deadline (uint256) and permit signature (64/65 bytes).
* Deadline and signature should be pack encoded together.
* Signature can be standard (65 bytes) or compact (64 bytes) defined in EIP-2098.
*/
function _permit(MultiToken.Asset memory asset, address origin, bytes memory permit) internal {
if (permit.length > 0)
asset.permit(origin, address(this), permit);
}
/*----------------------------------------------------------*|
|* # ERC721/1155 RECEIVED HOOKS *|
|*----------------------------------------------------------*/
/**
* @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
* by `operator` from `from`, this function is called.
*
* It must return its Solidity selector to confirm the token transfer.
* If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
*
* @return `IERC721Receiver.onERC721Received.selector` if transfer is allowed
*/
function onERC721Received(
address operator,
address /*from*/,
uint256 /*tokenId*/,
bytes calldata /*data*/
) override external view returns (bytes4) {
if (operator != address(this))
revert UnsupportedTransferFunction();
return IERC721Receiver.onERC721Received.selector;
}
/**
* @dev Handles the receipt of a single ERC1155 token type. This function is
* called at the end of a `safeTransferFrom` after the balance has been updated.
* To accept the transfer, this must return
* `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))`
* (i.e. 0xf23a6e61, or its own function selector).
* @return `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))` if transfer is allowed
*/
function onERC1155Received(
address operator,
address /*from*/,
uint256 /*id*/,
uint256 /*value*/,
bytes calldata /*data*/
) override external view returns (bytes4) {
if (operator != address(this))
revert UnsupportedTransferFunction();
return IERC1155Receiver.onERC1155Received.selector;
}
/**
* @dev Handles the receipt of a multiple ERC1155 token types. This function
* is called at the end of a `safeBatchTransferFrom` after the balances have
* been updated. To accept the transfer(s), this must return
* `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))`
* (i.e. 0xbc197c81, or its own function selector).
* @return `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))` if transfer is allowed
*/
function onERC1155BatchReceived(
address /*operator*/,
address /*from*/,
uint256[] calldata /*ids*/,
uint256[] calldata /*values*/,
bytes calldata /*data*/
) override external pure returns (bytes4) {
revert UnsupportedTransferFunction();
}
/*----------------------------------------------------------*|
|* # SUPPORTED INTERFACES *|
|*----------------------------------------------------------*/
/**
* @dev Returns true if this contract implements the interface defined by
* `interfaceId`. See the corresponding
* https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
* to learn more about how these ids are created.
*
* This function call must use less than 30 000 gas.
*/
function supportsInterface(bytes4 interfaceId) external pure virtual override returns (bool) {
return
interfaceId == type(IERC165).interfaceId ||
interfaceId == type(IERC721Receiver).interfaceId ||
interfaceId == type(IERC1155Receiver).interfaceId;
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.16;
/**
* @title PWN Fee Calculator
* @notice Library that calculates fee amount for given loan amount.
*/
library PWNFeeCalculator {
string internal constant VERSION = "1.0";
/**
* @notice Compute fee amount.
* @param fee Fee value in basis points. Value of 100 is 1% fee.
* @param loanAmount Amount of an asset used as a loan credit.
* @return feeAmount Amount of a loan asset that represents a protocol fee.
* @return newLoanAmount New amount of a loan credit asset, after deducting protocol fee.
*/
function calculateFeeAmount(uint16 fee, uint256 loanAmount) internal pure returns (uint256 feeAmount, uint256 newLoanAmount) {
if (fee == 0)
return (0, loanAmount);
unchecked {
if ((loanAmount * fee) / fee == loanAmount)
feeAmount = loanAmount * uint256(fee) / 1e4;
else
feeAmount = loanAmount / 1e4 * uint256(fee);
}
newLoanAmount = loanAmount - feeAmount;
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.16;
import "MultiToken/MultiToken.sol";
library PWNLOANTerms {
/**
* @notice Struct defining a simple loan terms.
* @dev This struct is created by loan factories and never stored.
* @param lender Address of a lender.
* @param borrower Address of a borrower.
* @param expiration Unix timestamp (in seconds) setting up a default date.
* @param collateral Asset used as a loan collateral. For a definition see { MultiToken dependency lib }.
* @param asset Asset used as a loan credit. For a definition see { MultiToken dependency lib }.
* @param loanRepayAmount Amount of a loan asset to be paid back.
*/
struct Simple {
address lender;
address borrower;
uint40 expiration;
MultiToken.Asset collateral;
MultiToken.Asset asset;
uint256 loanRepayAmount;
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.16;
import "@pwn/loan/terms/PWNLOANTerms.sol";
/**
* @title PWN Simple Loan Terms Factory Interface
* @notice Interface of a loan factory contract that builds a simple loan terms.
*/
abstract contract PWNSimpleLoanTermsFactory {
uint32 public constant MIN_LOAN_DURATION = 600; // 10 min
/**
* @notice Build a simple loan terms from given data.
* @dev This function should be called only by contracts working with simple loan terms.
* @param caller Caller of a create loan function on a loan contract.
* @param factoryData Encoded data for a loan terms factory.
* @param signature Signed loan factory data.
* @return loanTerms Simple loan terms struct created from a loan factory data.
*/
function createLOANTerms(
address caller,
bytes calldata factoryData,
bytes calldata signature
) external virtual returns (PWNLOANTerms.Simple memory loanTerms);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.16;
import "MultiToken/MultiToken.sol";
import "@pwn/config/PWNConfig.sol";
import "@pwn/hub/PWNHub.sol";
import "@pwn/hub/PWNHubTags.sol";
import "@pwn/loan/lib/PWNFeeCalculator.sol";
import "@pwn/loan/terms/PWNLOANTerms.sol";
import "@pwn/loan/terms/simple/factory/PWNSimpleLoanTermsFactory.sol";
import "@pwn/loan/token/IERC5646.sol";
import "@pwn/loan/token/PWNLOAN.sol";
import "@pwn/loan/PWNVault.sol";
import "@pwn/PWNErrors.sol";
/**
* @title PWN Simple Loan
* @notice Contract managing a simple loan in PWN protocol.
* @dev Acts as a vault for every loan created by this contract.
*/
contract PWNSimpleLoan is PWNVault, IERC5646, IPWNLoanMetadataProvider {
string internal constant VERSION = "1.0";
uint256 public constant MAX_EXPIRATION_EXTENSION = 2_592_000; // 30 days
/*----------------------------------------------------------*|
|* # VARIABLES & CONSTANTS DEFINITIONS *|
|*----------------------------------------------------------*/
PWNHub immutable internal hub;
PWNLOAN immutable internal loanToken;
PWNConfig immutable internal config;
/**
* @notice Struct defining a simple loan.
* @param status 0 == none/dead || 2 == running/accepted offer/accepted request || 3 == paid back || 4 == expired.
* @param borrower Address of a borrower.
* @param expiration Unix timestamp (in seconds) setting up a default date.
* @param loanAssetAddress Address of an asset used as a loan credit.
* @param loanRepayAmount Amount of a loan asset to be paid back.
* @param collateral Asset used as a loan collateral. For a definition see { MultiToken dependency lib }.
*/
struct LOAN {
uint8 status;
address borrower;
uint40 expiration;
address loanAssetAddress;
uint256 loanRepayAmount;
MultiToken.Asset collateral;
}
/**
* Mapping of all LOAN data by loan id.
*/
mapping (uint256 => LOAN) private LOANs;
/*----------------------------------------------------------*|
|* # EVENTS & ERRORS DEFINITIONS *|
|*----------------------------------------------------------*/
/**
* @dev Emitted when a new loan in created.
*/
event LOANCreated(uint256 indexed loanId, PWNLOANTerms.Simple terms);
/**
* @dev Emitted when a loan is paid back.
*/
event LOANPaidBack(uint256 indexed loanId);
/**
* @dev Emitted when a repaid or defaulted loan is claimed.
*/
event LOANClaimed(uint256 indexed loanId, bool indexed defaulted);
/**
* @dev Emitted when a LOAN token holder extends loan expiration date.
*/
event LOANExpirationDateExtended(uint256 indexed loanId, uint40 extendedExpirationDate);
/*----------------------------------------------------------*|
|* # CONSTRUCTOR *|
|*----------------------------------------------------------*/
constructor(address _hub, address _loanToken, address _config) {
hub = PWNHub(_hub);
loanToken = PWNLOAN(_loanToken);
config = PWNConfig(_config);
}
/*----------------------------------------------------------*|
|* # CREATE LOAN *|
|*----------------------------------------------------------*/
/**
* @notice Create a new loan by minting LOAN token for lender, transferring loan asset to a borrower and a collateral to a vault.
* @dev The function assumes a prior token approval to a contract address or signed permits.
* @param loanTermsFactoryContract Address of a loan terms factory contract. Need to have `SIMPLE_LOAN_TERMS_FACTORY` tag in PWN Hub.
* @param loanTermsFactoryData Encoded data for a loan terms factory.
* @param signature Signed loan factory data. Could be empty if an offer / request has been made via on-chain transaction.
* @param loanAssetPermit Permit data for a loan asset signed by a lender.
* @param collateralPermit Permit data for a collateral signed by a borrower.
* @return loanId Id of a newly minted LOAN token.
*/
function createLOAN(
address loanTermsFactoryContract,
bytes calldata loanTermsFactoryData,
bytes calldata signature,
bytes calldata loanAssetPermit,
bytes calldata collateralPermit
) external returns (uint256 loanId) {
// Check that loan terms factory contract is tagged in PWNHub
if (hub.hasTag(loanTermsFactoryContract, PWNHubTags.SIMPLE_LOAN_TERMS_FACTORY) == false)
revert CallerMissingHubTag(PWNHubTags.SIMPLE_LOAN_TERMS_FACTORY);
// Build PWNLOANTerms.Simple by loan factory
PWNLOANTerms.Simple memory loanTerms = PWNSimpleLoanTermsFactory(loanTermsFactoryContract).createLOANTerms({
caller: msg.sender,
factoryData: loanTermsFactoryData,
signature: signature
});
// Check loan asset validity
if (MultiToken.isValid(loanTerms.asset) == false)
revert InvalidLoanAsset();
// Check collateral validity
if (MultiToken.isValid(loanTerms.collateral) == false)
revert InvalidCollateralAsset();
// Mint LOAN token for lender
loanId = loanToken.mint(loanTerms.lender);
// Store loan data under loan id
LOAN storage loan = LOANs[loanId];
loan.status = 2;
loan.borrower = loanTerms.borrower;
loan.expiration = loanTerms.expiration;
loan.loanAssetAddress = loanTerms.asset.assetAddress;
loan.loanRepayAmount = loanTerms.loanRepayAmount;
loan.collateral = loanTerms.collateral;
emit LOANCreated(loanId, loanTerms);
// Transfer collateral to Vault
_permit(loanTerms.collateral, loanTerms.borrower, collateralPermit);
_pull(loanTerms.collateral, loanTerms.borrower);
// Permit spending if permit data provided
_permit(loanTerms.asset, loanTerms.lender, loanAssetPermit);
uint16 fee = config.fee();
if (fee > 0) {
// Compute fee size
(uint256 feeAmount, uint256 newLoanAmount) = PWNFeeCalculator.calculateFeeAmount(fee, loanTerms.asset.amount);
if (feeAmount > 0) {
// Transfer fee amount to fee collector
loanTerms.asset.amount = feeAmount;
_pushFrom(loanTerms.asset, loanTerms.lender, config.feeCollector());
// Set new loan amount value
loanTerms.asset.amount = newLoanAmount;
}
}
// Transfer loan asset to borrower
_pushFrom(loanTerms.asset, loanTerms.lender, loanTerms.borrower);
}
/*----------------------------------------------------------*|
|* # REPAY LOAN *|
|*----------------------------------------------------------*/
/**
* @notice Repay running loan.
* @dev Any address can repay a running loan, but a collateral will be transferred to a borrower address associated with the loan.
* Repay will transfer a loan asset to a vault, waiting on a LOAN token holder to claim it.
* The function assumes a prior token approval to a contract address or a signed permit.
* @param loanId Id of a loan that is being repaid.
* @param loanAssetPermit Permit data for a loan asset signed by a borrower.
*/
function repayLOAN(
uint256 loanId,
bytes calldata loanAssetPermit
) external {
LOAN storage loan = LOANs[loanId];
uint8 status = loan.status;
// Check that loan is not from a different loan contract
if (status == 0)
revert NonExistingLoan();
// Check that loan is running
else if (status != 2)
revert InvalidLoanStatus(status);
// Check that loan is not expired
if (loan.expiration <= block.timestamp)
revert LoanDefaulted(loan.expiration);
// Move loan to repaid state
loan.status = 3;
// Transfer repaid amount of loan asset to Vault
MultiToken.Asset memory repayLoanAsset = MultiToken.Asset({
category: MultiToken.Category.ERC20,
assetAddress: loan.loanAssetAddress,
id: 0,
amount: loan.loanRepayAmount
});
_permit(repayLoanAsset, msg.sender, loanAssetPermit);
_pull(repayLoanAsset, msg.sender);
// Transfer collateral back to borrower
_push(loan.collateral, loan.borrower);
emit LOANPaidBack(loanId);
}
/*----------------------------------------------------------*|
|* # CLAIM LOAN *|
|*----------------------------------------------------------*/
/**
* @notice Claim a repaid or defaulted loan.
* @dev Only a LOAN token holder can claim a repaid or defaulted loan.
* Claim will transfer the repaid loan asset or collateral to a LOAN token holder address and burn the LOAN token.
* @param loanId Id of a loan that is being claimed.
*/
function claimLOAN(uint256 loanId) external {
LOAN storage loan = LOANs[loanId];
// Check that caller is LOAN token holder
if (loanToken.ownerOf(loanId) != msg.sender)
revert CallerNotLOANTokenHolder();
if (loan.status == 0) {
revert NonExistingLoan();
}
// Loan has been paid back
else if (loan.status == 3) {
MultiToken.Asset memory loanAsset = MultiToken.Asset({
category: MultiToken.Category.ERC20,
assetAddress: loan.loanAssetAddress,
id: 0,
amount: loan.loanRepayAmount
});
// Delete loan data & burn LOAN token before calling safe transfer
_deleteLoan(loanId);
// Transfer repaid loan to lender
_push(loanAsset, msg.sender);
emit LOANClaimed(loanId, false);
}
// Loan is running but expired
else if (loan.status == 2 && loan.expiration <= block.timestamp) {
MultiToken.Asset memory collateral = loan.collateral;
// Delete loan data & burn LOAN token before calling safe transfer
_deleteLoan(loanId);
// Transfer collateral to lender
_push(collateral, msg.sender);
emit LOANClaimed(loanId, true);
}
// Loan is in wrong state or from a different loan contract
else {
revert InvalidLoanStatus(loan.status);
}
}
function _deleteLoan(uint256 loanId) private {
loanToken.burn(loanId);
delete LOANs[loanId];
}
/*----------------------------------------------------------*|
|* # EXTEND LOAN EXPIRATION DATE *|
|*----------------------------------------------------------*/
/**
* @notice Enable lender to extend loans expiration date.
* @dev Only LOAN token holder can call this function.
* Extending the expiration date of a repaid loan is allowed, but considered a lender mistake.
* The extended expiration date has to be in the future, be later than the current expiration date, and cannot be extending the date by more than `MAX_EXPIRATION_EXTENSION`.
* @param loanId Id of a LOAN to extend its expiration date.
* @param extendedExpirationDate New LOAN expiration date.
*/
function extendLOANExpirationDate(uint256 loanId, uint40 extendedExpirationDate) external {
// Check that caller is LOAN token holder
// This prevents from extending non-existing loans
if (loanToken.ownerOf(loanId) != msg.sender)
revert CallerNotLOANTokenHolder();
LOAN storage loan = LOANs[loanId];
// Check extended expiration date
if (extendedExpirationDate > uint40(block.timestamp + MAX_EXPIRATION_EXTENSION)) // to protect lender
revert InvalidExtendedExpirationDate();
if (extendedExpirationDate <= uint40(block.timestamp)) // have to extend expiration futher in time
revert InvalidExtendedExpirationDate();
if (extendedExpirationDate <= loan.expiration) // have to be later than current expiration date
revert InvalidExtendedExpirationDate();
// Extend expiration date
loan.expiration = extendedExpirationDate;
emit LOANExpirationDateExtended(loanId, extendedExpirationDate);
}
/*----------------------------------------------------------*|
|* # GET LOAN *|
|*----------------------------------------------------------*/
/**
* @notice Return a LOAN data struct associated with a loan id.
* @param loanId Id of a loan in question.
* @return loan LOAN data struct or empty struct if the LOAN doesn't exist.
*/
function getLOAN(uint256 loanId) external view returns (LOAN memory loan) {
loan = LOANs[loanId];
loan.status = _getLOANStatus(loanId);
}
function _getLOANStatus(uint256 loanId) private view returns (uint8) {
LOAN storage loan = LOANs[loanId];
return (loan.status == 2 && loan.expiration <= block.timestamp) ? 4 : loan.status;
}
/*----------------------------------------------------------*|
|* # IPWNLoanMetadataProvider *|
|*----------------------------------------------------------*/
/**
* @notice See { IPWNLoanMetadataProvider.sol }.
*/
function loanMetadataUri() override external view returns (string memory) {
return config.loanMetadataUri(address(this));
}
/*----------------------------------------------------------*|
|* # ERC5646 *|
|*----------------------------------------------------------*/
/**
* @dev See {IERC5646-getStateFingerprint}.
*/
function getStateFingerprint(uint256 tokenId) external view virtual override returns (bytes32) {
LOAN storage loan = LOANs[tokenId];
if (loan.status == 0)
return bytes32(0);
// The only mutable state properties are:
// - status, expiration
// Status is updated for expired loans based on block.timestamp.
// Others don't have to be part of the state fingerprint as it does not act as a token identification.
return keccak256(abi.encode(
_getLOANStatus(tokenId),
loan.expiration
));
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.16;
/**
* @dev Interface of the ERC5646 standard, as defined in the https://eips.ethereum.org/EIPS/eip-5646.
*/
interface IERC5646 {
/**
* @notice Function to return current token state fingerprint.
* @param tokenId Id of a token state in question.
* @return Current token state fingerprint.
*/
function getStateFingerprint(uint256 tokenId) external view returns (bytes32);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.16;
/**
* @title PWN Loan Metadata Provider
* @notice Interface for a provider of a LOAN token metadata.
* @dev Loan contracts should implement this interface.
*/
interface IPWNLoanMetadataProvider {
/**
* @notice Get a loan metadata uri for a LOAN token minted by this contract.
* @return LOAN token metadata uri.
*/
function loanMetadataUri() external view returns (string memory);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.16;
import "openzeppelin-contracts/contracts/token/ERC721/ERC721.sol";
import "@pwn/hub/PWNHubAccessControl.sol";
import "@pwn/loan/token/IERC5646.sol";
import "@pwn/loan/token/IPWNLoanMetadataProvider.sol";
import "@pwn/PWNErrors.sol";
/**
* @title PWN LOAN token
* @notice A LOAN token representing a loan in PWN protocol.
* @dev Token doesn't hold any loan logic, just an address of a loan contract that minted the LOAN token.
* PWN LOAN token is shared between all loan contracts.
*/
contract PWNLOAN is PWNHubAccessControl, IERC5646, ERC721 {
/*----------------------------------------------------------*|
|* # VARIABLES & CONSTANTS DEFINITIONS *|
|*----------------------------------------------------------*/
/**
* @dev Last used LOAN id. First LOAN id is 1. This value is incremental.
*/
uint256 public lastLoanId;
/**
* @dev Mapping of a LOAN id to a loan contract that minted the LOAN token.
*/
mapping (uint256 => address) public loanContract;
/*----------------------------------------------------------*|
|* # EVENTS DEFINITIONS *|
|*----------------------------------------------------------*/
/**
* @dev Emitted when a new LOAN token is minted.
*/
event LOANMinted(uint256 indexed loanId, address indexed loanContract, address indexed owner);
/**
* @dev Emitted when a LOAN token is burned.
*/
event LOANBurned(uint256 indexed loanId);
/*----------------------------------------------------------*|
|* # CONSTRUCTOR *|
|*----------------------------------------------------------*/
constructor(address hub) PWNHubAccessControl(hub) ERC721("PWN LOAN", "LOAN") {
}
/*----------------------------------------------------------*|
|* # TOKEN LIFECYCLE *|
|*----------------------------------------------------------*/
/**
* @notice Mint a new LOAN token.
* @dev Only an address with associated `ACTIVE_LOAN` tag in PWN Hub can call this function.
* @param owner Address of a LOAN token receiver.
* @return loanId Id of a newly minted LOAN token.
*/
function mint(address owner) external onlyActiveLoan returns (uint256 loanId) {
loanId = ++lastLoanId;
loanContract[loanId] = msg.sender;
_mint(owner, loanId);
emit LOANMinted(loanId, msg.sender, owner);
}
/**
* @notice Burn a LOAN token.
* @dev Any address that is associated with given loan id can call this function.
* It is enabled to let deprecated loan contracts repay and claim existing loans.
* @param loanId Id of a LOAN token to be burned.
*/
function burn(uint256 loanId) external {
if (loanContract[loanId] != msg.sender)
revert InvalidLoanContractCaller();
delete loanContract[loanId];
_burn(loanId);
emit LOANBurned(loanId);
}
/*----------------------------------------------------------*|
|* # METADATA *|
|*----------------------------------------------------------*/
/**
* @notice Return a LOAN token metadata uri base on a loan contract that minted the token.
* @param tokenId Id of a LOAN token.
* @return Metadata uri for given token id (loan id).
*/
function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
_requireMinted(tokenId);
return IPWNLoanMetadataProvider(loanContract[tokenId]).loanMetadataUri();
}
/*----------------------------------------------------------*|
|* # ERC5646 *|
|*----------------------------------------------------------*/
/**
* @dev See {IERC5646-getStateFingerprint}.
*/
function getStateFingerprint(uint256 tokenId) external view virtual override returns (bytes32) {
address _loanContract = loanContract[tokenId];
if (_loanContract == address(0))
return bytes32(0);
return IERC5646(_loanContract).getStateFingerprint(tokenId);
}
/*----------------------------------------------------------*|
|* # ERC165 *|
|*----------------------------------------------------------*/
/**
* @dev See {IERC165-supportsInterface}.
*/
function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
return super.supportsInterface(interfaceId) ||
interfaceId == type(IERC5646).interfaceId;
}
}